// SPDX-License-Identifier: MIT
pragma solidity ^0.8.26;

import {Test} from "forge-std/Test.sol";
import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {Sinopia, IIntake} from "src/Sinopia.sol";

contract ProofIMD is ERC20 {
    constructor() ERC20("Mock IMD", "IMD") {}

    function mint(address to, uint256 amount) external {
        _mint(to, amount);
    }
}

contract ProofIntake is IIntake {
    IERC20 public immutable imd;
    uint256 public count;

    constructor(IERC20 imd_) {
        imd = imd_;
    }

    function requestWithFailure(bytes32, bytes calldata, Callback calldata, bytes4, address, uint256 amount)
        external
        returns (bytes32 requestId)
    {
        imd.transferFrom(msg.sender, address(this), amount);
        requestId = bytes32(++count);
    }
}

/// A winner whose commission was delivered with a valid, revealable result must not be able to take
/// the winning bid back. Today the winner waits out REVEAL_TIMEOUT, calls expire() and claimRefund(),
/// pays only the 0.5 IMD job fee, nothing is burned and no NFT is minted, while the painting is public.
contract WinnerSkipsBurnTest is Test {
    ProofIMD imd;
    ProofIntake intake;
    Sinopia fresco;
    address alice = address(0xA11CE);
    address bob = address(0xB0B);
    string constant BRIEF = "A blue river over warm hills";

    function setUp() public {
        imd = new ProofIMD();
        intake = new ProofIntake(imd);
        fresco = new Sinopia(address(intake), address(imd));
        imd.mint(alice, 100 ether);
        imd.mint(bob, 100 ether);
        vm.prank(alice);
        imd.approve(address(fresco), type(uint256).max);
        vm.prank(bob);
        imd.approve(address(fresco), type(uint256).max);
    }

    function _validResult() internal pure returns (bytes memory) {
        return bytes(
            '{"complete":true,"files":[{"hash":"a0caa7dcf140dc65ac5c606be9151dac6c7f00d021e288646a596c96c6ce5309","mediaType":"image/png","name":"image"}],"jobId":"23e66772-0986-4e80-b7f2-cd1882f5e634","state":"completed"}'
        );
    }

    function testWinnerCannotRecoverBidAfterValidDelivery() public {
        vm.prank(bob);
        fresco.bid(1, 0.55 ether, BRIEF);
        vm.prank(alice);
        fresco.bid(1, 10 ether, BRIEF); // alice wins with 10 IMD
        vm.warp(fresco.getRound(1).endTime);
        fresco.settle(1);
        bytes32 id = fresco.getRound(1).requestId;
        bytes memory json = _validResult();
        vm.prank(address(intake));
        fresco.onResult(id, keccak256(json), "ipfs://painting/result.json");

        // The result is valid: reveal(1, json) would mint and burn. Only the winner has a reason not to.
        vm.warp(block.timestamp + 7 days + 1);
        vm.startPrank(alice);
        try fresco.expire(1) {} catch {}
        try fresco.claimRefund(1) {} catch {}
        try fresco.claim() {} catch {}
        vm.stopPrank();

        // Expected: the 9.5 IMD above the job fee stays committed (burned on reveal, or still escrowed).
        assertEq(imd.balanceOf(alice), 90 ether, "winner took the bid back after a valid delivery");
    }
}